全面理解Gradle - 定義Task
之前我們講述了Groovy的語法，還講述了Gradle的執行時序，本篇文章講述下Task的定義。
Task可以理解為Gradle的執行單元，實在是太重要了。根據前面的分析，Gradle通過一個個task來完成具體的構建任務，下面我們來看下Task的定義。
最簡單直接，通過如下方式來定義：
task myTask {
println "config myTask"
}
我們執行下
renyugang$ gradle myTask
config myTask
再執行下
renyugang$ gradle clean
config myTask
可以看出，通過上述方式定義的task，括號內部的代碼會在配置階段執行，也就是說，只要我執行任何一個task，那段代碼都會執行，因為每個task執行之前都需要進行一遍完整的配置。
但是很多時候我們并不需要寫配置代碼，我們想要括號內的代碼僅僅在執行我們的task的時候才執行，這個時候可以通過doFirst或者doLast來完成。
- doFirst：task執行時，最開始的操作
- doLast：task執行時，最后的操作
// 定義并配置myTask
task myTask {
println "config myTask"
}
myTask.doLast {
println "after execute myTask"
}
myTask.doFirst {
println "before execute myTask"
}
執行結果如下
config myTask
:app:myTask
before execute myTask
after execute myTask
除此之外，doLast還有一個等價的操作leftShift，leftShift還可以縮寫為<<，因此下面的三種實現效果等價：
myTask.doLast {
println "after execute myTask"
}
myTask.leftShift {
println "after execute myTask"
}
myTask << {
println "after execute myTask"
}
在上面的demo中，myTask真正執行的時候啥都沒干，它只是在執行的最開始和最后做了一些事情。
其實，通過@TaskAction操作符也可以指定一個Task執行時要做的事情，它區別于doFirst和doLast，不過@TaskAction平時用的較少，這里簡單示范下：
class RygTask extends DefaultTask {
String message = 'This is RygTask'
// @TaskAction 表示該Task要執行的動作,即在調用該Task時，hello()方法將被執行
@TaskAction
def hello(){
println "Hello world. $message"
}
}
// hello使用了默認的message值
task hello(type:RygTask)
// 重新設置了message的值
task hello1(type:RygTask){
message ="I am an android developer"
}
執行 gradle hello hello1
:app:hello
Hello world. This is RygTask
:app:hello1
Hello world. I am an android developer
除了上面的Task定義方式以外，Gradle本身還提供了一些已有的Task供我們使用，比如Copy、Delete、Sync等。因此我們定義Task的時候是可以繼承已有的Task，比如我們可以繼承自系統的Copy Task來完成文件的拷貝操作。
task myTask(type: Copy) { configure closure }
除了這種方式以外，我們還可以通過API來動態創建Task，API也有很多，這里介紹幾個最常用的（Gradle水很深，API特別靈活，大家記住最常用的就好）。
// 下面三種定義也一模一樣
task myTask << {
println "after execute myTask"
}
project.task('myTask').doLast {
println "after execute myTask"
}
project.tasks.create('myTask').doLast {
println "after execute myTask"
}
定義Task的時候是可以指定很多參數的，如下所示：
| 參數 | 含義 | 默認值 |
|---|---|---|
| name | task的名字 | 不能為空，必須指定 |
| type | task的“父類” | DefaultTask |
| overwrite | 是否替換已經存在的task | false |
| dependsOn | task依賴的task的集合 | [] |
| group | task屬于哪個組 | null |
| description | task的描述 | null |
在上面的例子中都沒涉及參數，下面舉個帶參數的栗子。
task myTask1 << {
println "execute myTask1"
}
task myTask2 << {
println "execute myTask2"
}
// 定義一個名字為rygTask的task，屬于renyugang分組，并且依賴myTask1和myTask2兩個task。
project.task('rygTask', group: "renyugang", description: "我自己的Task", dependsOn: ["myTask1", "myTask2"] ).doLast {
println "execute rygTask"
}
通過 Gradle tasks 來查看：
Publishing tasks
----------------
bintrayUpload - Publishes artifacts to bintray.com.
Renyugang tasks
---------------
rygTask - 我自己的Task
Upload tasks
------------
uploadArchives - Uploads all artifacts belonging to configuration ':AndroidStub:archives'
嘗試執行 gradle rygTask ，結果如下：
:app:myTask1
execute myTask1
:app:myTask2
execute myTask2
:app:rygTask
execute rygTask
結果不用我解釋了，相信大家都能看懂。
補充說明
- Gradle命令是支持連在一起拼寫的，比如 gradle hello hello1 ，那么gradle將會先執行hello，然后再執行hello1。
- Gradle命令是可以縮寫的，前提是這個縮寫能夠唯一地限定一個task。比如rygTask，那么執行的時候就可以縮寫為 gradle rTask 。
最后，定義task的API很多，我介紹了最常用的部分，剩下的細節還是需要大家查看Gradle文檔，其實學習Gradle就是一個查文檔的過程。如下幾個文檔，大家讀讀。
來自：http://blog.csdn.net/singwhatiwanna/article/details/78898113