作為 Android 開發者必須了解的 Gradle 知識

pwfk5527 7年前發布 | 14K 次閱讀 Gradle 安卓開發 Android開發移動開發

在Android開發中，很多時候我們不需要修改 *.gradle 文件太多，我們添加依賴、修改target compile、最低支持API level，或者修改簽名配置和build類型。其它更復雜一些邏輯，我們最后可能就是從Stack Overflow中copy了一些自己也不太懂的代碼。本文中我們將一步一步介紹Android工程中用到的gradle文件及其背后的原理。

1. Groovy

1.1 語法

Gradle文件其實是用Groovy腳本寫的，我們都會寫java，所以入門Groovy非常簡單。首先我們需要了解一下幾點：

1.調用至少包含一個參數的方法時不需要使用括號：

def printAge(String name, int age) {
    print("$name is $age years old")
}

def printEmptyLine() {
    println()
}

def callClosure(Closure closure) {
    closure()
}

printAge "John", 24 // Will print "John is 24 years old"
printEmptyLine() // Will, well, print empty line
callClosure { println("From closure") } // Will print "From closure"

2.如果方法的最后一個參數是閉包（或者說是lambda表達式），可以寫在括號外(注：這個特性很重要，gradle文件中的很多配置其實都是參數為閉包的方法)：

def callWithParam(String param, Closure<String> closure) {
    closure(param)
}

callWithParam("param", { println it }) // Will print "param"
callWithParam("param") { println it } // Will print "param"
callWithParam "param", { println it } // Will print "param"

3.對于Groovy方法中命名過的參數，會被轉移到一個map中做為方法的第一個參數，那些沒有命名的參數則加在參數列表之后：

def printPersonInfo(Map<String, Object> person) {
    println("${person.name} is ${person.age} years old")
}

def printJobInfo(Map<String, Object> job, String employeeName) {
    println("$employeeName works as ${job.title} at ${job.company}")
}

printPersonInfo name: "John", age: 24
printJobInfo "John", title: "Android developer", company: "Tooploox"

這段程序會打印“John is 24 years old”和“John works as Android developer at Tooploox”，方法調用的參數可以是亂序的，map會被作為第一個參數傳入！這里的方法調用也省略了括號。

1.2 閉包

閉包是一個非常重要的特性，需要解釋一下。閉包可以理解為lambada。他們是一段可以被執行的代碼，可以有參數列表和返回值。我們可以改變一個閉包的委托：

class WriterOne {
    def printText(str) {
        println "Printed in One: $str"
    }
}

class WriterTwo {
    def printText(str) {
        println "Printed in Two: $str"
    }
}

def printClosure = {
    printText "I come from a closure"
}

printClosure.delegate = new WriterOne()
printClosure() // will print "Printed in One: I come from a closure
printClosure.delegate = new WriterTwo()
printClosure() // will print "Printed in Two: I come from a closure

我們可以看到 printClosure 調用了不同委托的 printText 方法，之后會解析這個特性在gradle中的重要性。

2. Gradle

2.1 腳本文件

有三個主要的gradle腳本，每個都是一個代碼塊。

build.gradle 文件，針對 Project 對象
settings.gradle文件，針對 Settings 對象
全局配置的初始化gradle腳本，針對 Gradle 實例

2.2 Projects

gradle 構建一般包含多個Project(在Android中每個module對應這里的project)，project中包含tasks。一般至少有一個root project，包含很多subprojects，subproject也可以嵌套project（注：Android 中對應每個library module還可以依賴其它library module）。

3. 構建基于Gradle的Android工程

Android工程中我們一般有如下的結構：

1是root project的setting文件，被 Settings 執行

2是root project的build配置

3是App project的屬性文件，會被注入到 App的 Settings 中

4是App project的build配置

3.1 創建gradle工程

我們新建一個文件夾，命名為 example ， cd 進入后執行 gradle projects 命令，之后就已經擁有一個gradle project了：

$ gradle projects
:projects
------------------------------------------------------------
Root project
------------------------------------------------------------
Root project 'example'
No sub-projects
To see a list of the tasks of a project, run gradle <project-path>:tasks
For example, try running gradle :tasks
BUILD SUCCESSFUL
Total time: 0.741 secs

3.2 配置projects層級

如果我們要建立一個默認的Android project（空的root project和一個包含Application的app project），我們就需要配置 settings.gradle ， the documentation 中介紹 settings.gradle ：

聲明需要實例化的配置和build的project的層級體系配置

我們通過void include( String [] projectPaths)方法來添加projects：

這里的冒號 : 用于分隔子project，可以參考這里 here 。因此我們在這里寫 :app ，而不是直接寫 app 。

在 settings.gradle 中寫 rootProject.name = <<name>> 也是一個比較好的實踐。如果沒有寫，那么root project 的默認名字就是project所在文件夾的名字。

3.3 配置Android 子project

我們已經配置了root project的 build.gradle ，現在來看看如何配置Android project。

從 user guide 可以知道我們首先要為app project配置 com.android.application 插件，我們來看看 apply 方法：

void apply(Closure closure)
void apply(Map<String, ?> options)
void apply(Action<? super ObjectConfigurationAction> action)

盡管第三個方法很重要，我們通常使用是第二個方法，它用到我們之前提到的特性，通過map來傳遞參數。通過文檔我們可以查看可以使用哪些參數：

void apply(Map(<String, ?> options)

以下是可用的參數：

from: 可以引入一個腳本apply(...)，如 apply from: "bintray.gradle" 從而導入一個可用腳本。

plugin: apply的plugin的id或者實現類

to: 委托目標

我們知道需要傳遞一個id值作為 plugin 的參數，可以寫作： apply(plugin:'com.android.application') ，這里的括號也可以省略，我們在app的 build.gradle 中配置：

命令行中運行：

報錯了，找不到 com.android.application 的定義，這不奇怪，我們并沒有配置，但是gradle是如何查找Android的plugin jar包呢？在 user guide 可以找到答案，我們需要配置plugin的路徑。

現在我們可以在root project或者app的 build.gradle 中配置路徑，但是因為 buildscript 閉包是 ScriptHandler 執行的，其它子project也需要使用，因此最好配置在root project的 build.gradle 中：

buildscript {
    repositories {
        jcenter()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.0-beta2'
    }
}

如果我們在上邊的代碼中添加括號，那么就會發現其實都是帶有閉包參數的方法調用。如果我們研究下文檔，我們就可以知道是有哪些對象執行這些閉包的，總結如下：

buildscript(Closure) 是 Project 實例中調用的，傳遞的閉包的由 ScriptHandler 執行

repositories(Closure) 是在 ScriptHandler 實例中調用，傳遞的閉包由 RepositoryHandler 執行

dependencies(Closure) 是在 ScriptHandler 實例中調用，傳遞的閉包由 DependencyHandler 執行。

也就是說 jcenter() 是由 RepositoryHandler 調用

classpath(String) 是由 DependencyHandler(*) 調用

譯者注：如果這里看不懂的同學，可以再回頭看看groovy的語法部分，其實這里上邊的代碼都是方法，如buildscript是Project的方法，我們知道groovy語法中如果最后一個參數是閉包的話，可以不寫括號。

如果查看 DependencyHandler 的代碼，我們會發現其實沒有 classpath 這個方法，這是一種特殊的調用，我們在稍后討論。

3.4 配置Android subproject

如果我們現在執行Gradle task，依然有錯誤：

顯然，我們還沒有設置Android相關的配置，但是我們的Android plugin已經可以被正確apply了，我們增加一些配置：

android {
   buildToolsVersion "25.0.1"
   compileSdkVersion 25
}

到這里我們知道，android方法被加入到了 Project 實例中，閉包傳遞給了delegate（這里是AppExtension），定義了 buildToolsVersion 和 compileSdkVersion 方法，Android plugin使用這種方式接收所有的配置，包括default configuration，flavors等等。

想要執行gradle task，還需要兩個文件： AndroidManifest.xml 和 local.properties ， local.properties 中配置 sdk.dir ，（或者在系統環境中配置 ANDROID_HOME ）,指向Android SDK的位置。

3.5 擴展

android 方法是如何出現在 Project 實例中的呢，還有我們的build.gradle是怎樣被執行的？簡單的說，Android plugin 用android這個名字注冊 AppExtension 類為 extension 。這個超出了本文的范圍，但是我們要知道Gradle可以為每一個注冊過的 plugin增加閉包配置。

3.6 依賴

還有一個重要的部分，dependencies還沒有討論：

dependencies {
    compile 'io.reactivex.rxjava2:rxjava:2.0.4'
    testCompile 'junit:junit:4.12'
    annotationProcessor 'org.parceler:parceler:1.1.6'
}

為什么這里特殊呢，因為如果查看 DependencyHandler ，也就是執行這個閉包的委托，它是沒有 compile , testCompile 等方法的。這個問題是有意義的，如果我們隨意增加一個 freeCompile 'somelib' ，可以嗎？ DependencyHandler 不會定義所有的方法，其實這里涉及到Groory語音的另一個特性： methodMissing ，這允許在運行時catch對于未定義方法的調用。

實際上Gradle使用了 MethodMixIn 中聲明的 methodMissing ，類似的機制在為定義的屬性中也是一樣的。

相關的dependency操作可以在這里找到，它的行為如下：

如果未定義方法的調用方有至少一個參數，如果存在 configuration() 與被調用方法有相同的名字，那么就根據參數的類型和數量，調用具有相關參數的 doAdd 方法。

每個plugin都可以增進configuration到dependencies handler中，如Android插件增加了 compile, compileClasspath, testCompile 和一些其它配置 here ，Android 插件還增加了 annotationProcessor 配置，根據不同build類型和產品形式還有 <variant>Compile, <variant>TestCompile 等等。

由于 doAdd 是私有方法，一次這里調用的是公有的 add 方法，我們可以重寫上邊的代碼，但最后不要這樣做：

dependencies {
    add('compile', 'io.reactivex.rxjava2:rxjava:2.0.4')
    add('testCompile', 'junit:junit:4.12')
    add('annotationProcessor', 'org.parceler:parceler:1.1.6')
}

3.7 Flavors, build types, signing configs

我們看以下代碼：

productFlavors {
    prod {

    }

    dev {
        minSdkVersion 21
        multiDexEnabled true
    }
}

如果我們查看源碼，可以發現productFlavors是這樣聲明的：

void productFlavors(Action<? super 
NamedDomainObjectContainer<ProductFlavorDsl>> action) {
    action.execute(productFlavors)    
}

Action<T> 是Gradle中定義的由 T 執行的閉包

所有這里我們有了 NamedDomainObjectContainer ， NamedDomainObjectContainer 可以創建和配置多個 ProductFlavorDsl 類型的對象，并根據 ProductFlavorDsl 的名字保存 ProductFlavorDsl 。

這個容器可以使用動態方法創建指定類型的對象（這里的ProductFlavorDsl），并和名字一起存放在容器中，所以當我們使用 {} 參數調用 prod 方法時，他被 productFlavors 實例執行，執行說明如下：

NamedDomainObjectContainer 獲取到被調用方法的名字，生成 ProductFlavorDsl 對象，配置給定的閉包，保存方法名字到新的配置 ProductFlavorDsl 的映射。

Android plugin可以從 productFlavors 中獲取 ProductFlavorDsl ，我們可以把它作為屬性進行訪問： productFlavors.dev ，這樣我們就可以拿到名字為 dev 的 ProductFlavorDsl ，這也是我們可以寫 signingConfig signingConfigs.debug 的原因。

4. 總結

對于Android開發者來說，Gradle文件是非常常用的，并不是什么黑魔法。但是Gradle有很多約定，而且使用Groovy語言也增加了一些復雜性，知道這兩點，Gradle并不是什么魔法。希望了解通過這篇文章介紹的內容，即使是從stackoverflow中粘貼代碼，也能知道它背后的意義。

這是一篇譯文，原文作者對Android的gradle進行了比較深入的介紹，希望各位同學可以真正了解我們常用的gradle文件背后的原理，而不僅僅是簡單地配置gralde。文中有些不太容易理解的地方，可以根據文中給出的鏈接了解更多內容。

來自：http://www.jianshu.com/p/c31513f5f550

本文由用戶 pwfk5527 自行上傳分享，僅供網友學習交流。所有權歸原作者，若您的權利被侵害，請聯系管理員。

轉載本站原創文章，請注明出處，并保留原始鏈接、圖片水印。

本站是一個以用戶分享為主的開源技術平臺，歡迎各類分享！

本文地址：http://www.baiduhome.net/lib/view/open1487641403935.html

Gradle 安卓開發 Android開發移動開發